if函数多个条件多个结果并列(if函数多个条件多个结果)

Excel的Vlookup+IF公式组合，3个用法，太秀了！

Vlookup函数公式在工作中天天用，再搭配IF函数公式，强上加强，今天分享3个VLOOKUP结合IF函数公式组合应用实例

左边是员工编号，姓名和工资数据，需要根据员工姓名，查找员工编号，这是从右向左进行查找，正常VLOOKUP无法计算，只需要加上IF函数公式：

使用公式就能轻松得到结果

=VLOOKUP(E2,IF({1,0},B:B,A:A),2,0)

通用用法：

=VLOOKUP(查找值，IF({1,0},查找列，结果列)，2，0)

左边是各个月份的工资表，现在需要根据两个条件，来查找匹配工资数据

我们可以使用公式：

=VLOOKUP(E2&F2,IF({1,0},A:A&B:B,C:C),2,0)

同样是通过IF函数公式来构建两个查找列进行相连接

万能通用用法：

=VLOOKUP(查找值1&查找值2，IF({1,0}，查找列1&查找列2，结果列)，2，0)

根据部门，快速查找所有员工姓名和工资情况，如果不允许创建辅助项的情况下，我们就可以借助IF+INDIRECT+COUNTIFS来构建虚拟数组，所以我们使用的公式是：

=IFERROR(VLOOKUP($E$2&ROW(A1),IF({1,0},$A$2:$A$6&COUNTIFS(INDIRECT("A2:A"&ROW($2:$6)),$E$2),B$2:B$6),2,0),"")

向右向下填充，得到结果

关于这3个小技巧，你学会了么？动手试试吧！

当IF函数碰到多个条件，你应该如何使用呢？

【温馨提示】亲爱的朋友，阅读之前请您点击【关注】，您的支持将是我最大的动力！

IF函数是Excel中经常用的条件判断函数，有3个参数，第一个参数为条件，第二个参数为满足条件时返回的结果，第三个参数为不满足条件时返回的结果。

我们在使用IF函数时，一个条件用得比较多，也比较简单，如果碰到多个条件呢？今天阿钟老师分享一组多个条件的IF函数应用实例。

01.IF函数语法

用途：判断是否满足某个条件，如果满足返回一个值，如果不满足返回另一个值。

语法：IF（条件，满足条件返回的值，不满足条件返回的值）

02.IF函数单条件判断的使用方法

我们以判断表格中“语文”成绩是否及格为例。

在E2单元格输入公式：=IF(D2<60,"不及格","及格")

然后双击或下拉填充公式得出全部结果。

说明：公式中D2<60为条件，当满足条件时，返回“不及格”，否则返回“及格”。

03.IF函数多条件判断嵌套的使用方法

要求表格中“语文”、“数学”、“英语”三门成绩都超过90分显示“优秀”，否则显示空值。

用到的公式：

=IF(D2>90,IF(E2>90,IF(F2>90,"优秀",""),""),"")

说明：实例要求同时满足三个条件，公式中用了三个IF函数，第一个IF的条件为D2>90，满足时执行下一个IF函数，不满足返回“”，也就是空值；后面两个IF函数的原理和第一个相同。

Excel中IF函数最多嵌套64次。

04.IF函数多条件判断与AND函数组合使用方法

上例中三个条件我们可以用AND函数来实现，比起IF函数嵌套，在输入和阅读方面都有优越性。

公式：=IF(AND(D2>90,E2>90,F2>90),"优秀","")

是不是从书写上就比上例公式短了很多。

说明：公式中三个条件用AND函数组合。AND函数是一个逻辑函数，用于测试是否满足所有条件。

05.IF函数多条件判断与*（乘号）组合使用方法

比起AND函数判断是否满足所有条件更简单的就是用*（乘号）把所有条件连接起来。

公式：=IF((D2>90)*(E2>90)*(F2>90),"优秀","")

说明：逻辑值有2个，“真”和“假”，分别代表成立和不成立，用TRUE（或者1）和FALSE（或者0）表示。

知道了这些我们再来看看公式中条件的组成，第一个条件D2>90，成立时，得到的是“真”，也就是TRUE（或者1），第二、三个条件也是这样的原理，当三个条件都是“真”时，用数字来表示就是1*1*1，得到的结果还是1，代表条件成立；

如果三个条件中有任何一个为“假”，也就是有一个0时，三个数再怎么相乘都结果都是0，代表条件不成立。

06.IF函数多条件判断与OR函数组合使用方法

要求表格中“语文”、“数学”、“英语”三门成绩只要有一门不及格，就显示“补考”，否则显示空值。

公式：=IF(OR(D2<60,E2<60,F2<60),"补考","")

说明：公式中用OR函数连接了三个条件。OR函数也是一个逻辑函数，刚好AND相反，只要有一个条件满足，就返回“真”，所有条件都不满足时才返回“假”。

07.IF函数多条件判断与+（加号）组合使用方法

上例中OR函数可以用+（加号）代替。

公式：=IF((D2<60)+(E2<60)+(F2<60),"补考","")

小伙伴们看看*代替AND函数的讲解，自己理解一下，+是如何代替OR函数的，欢迎评价区留言讨论。

小伙伴们，在使用Excel中还碰到过哪些问题，评论区留言一起讨论学习，坚持原创不易，您的点赞转发就是对小编最大的支持，更多教程点击下方专栏学习。